sumif函數(shù)常見的幾種具體用法

一、SUMIF函數(shù)的一個怪異用途

Excel表格中的SUMIF函數(shù)在條件求和時經常使用，一般習慣于于根據某一列計算另一列的數(shù)字之和。

例1：假設置A列是部門，B列是姓名，C列是工資，可以用下面的公式算出所有財務部員工的工資總和：

=SUM(A1：A100，"財務部",C1:C100)

今天說的不是這個正規(guī)用法，而是給大家介紹一種看上去和SUMIF毫無關系的例子。

如下圖中，是一些不規(guī)則的數(shù)據，只關注填充顏色的區(qū)域，現(xiàn)在要計算所有A下面數(shù)字之和，看上去這個題沒有好的思路，其實這個題恰好可以用SUMIF函數(shù)輕松解決。

=SUMIF(B2:E7,B12,B3:E8)

分析一下這個公式，第二個參數(shù)是條件可以了解，第一個參數(shù)和第二個參數(shù)有什么關系呢?大家仔細看會發(fā)現(xiàn)第三個參數(shù)正好是第一個參數(shù)的區(qū)域向下偏移一個單位。

總結，SUMIF函數(shù)并不是只對規(guī)則區(qū)域求和，還可以對不規(guī)則的排列進行條件求和

二、SUMIF函數(shù)入門篇

SUMIF作為Excel2003中一個條件求和函數(shù)，在實際工作中發(fā)揮著強大的作用，雖然在2007以后被SUMIFS所取代，但它依舊是一個EXCEL函數(shù)的經典。特別是高級用法，依舊適用于后面的版本。

SUM是求和，IF是如果。如果什么。。就求和，其實就是按條件求和。它的結構如下：

SUMIF(條件判斷區(qū)域,條件，求和區(qū)域)

說明：

1 條件判斷區(qū)域。即然是條件求和，一是要有條件，二是要有判斷的區(qū)域，SUMIF的第二個參數(shù)就是求和的條件，第一個參數(shù)呢就是拿條件來這個區(qū)域進行對比的區(qū)域。第一個參數(shù)必須是單元格引用。

2、條件。按條件求和就得有條件，該條件可以是字符串("ABC"，可以用大于等對比符號連接起來的條件表達式(">100")，也可以使用通配符來表示匹配求和("AB*C")。

3、求和區(qū)域。求和函數(shù)可以沒有求和的區(qū)域算什么求和函數(shù)，該參數(shù)為單元格區(qū)域引用。如C2：C100。

4、如果求和區(qū)域和判斷區(qū)域是一個區(qū)域該怎么辦呢?如在C2：C100中計算大于100的數(shù)字之和。在這種情況下SUMIF函數(shù)由三個參數(shù)變換為兩個參數(shù)。即：

SUMIF(求和區(qū)域，條件)

例：如下圖所示。要求根據左表中的商家明細表，生成右側的匯總表，匯總出商家的總進貨量和總金額。

公式：

=SUMIF($A$2:$A$8,$F3,C$2:C$8)

公式說明：

$A$2:$A$8是判斷區(qū)域，拿F3的商家名稱在這個區(qū)域進行判斷是否相同，如果上同，就把C2：C8區(qū)域的金額進行求和。

如果只按C列進判斷求和呢?比如，計算C列金額大于200的金額之和。公式可以變換為：

SUMIF(C$2:C$8,">200")

三、SUMIF函數(shù)技巧篇

在學習了SUMIF函數(shù)入門篇后，在常用技巧篇中將學習SUMIF函數(shù)常用的一些技巧。

談到隔列求和，可能就會想到用數(shù)組公式，其實只需要用SUMIF函數(shù)就可以輕松實現(xiàn)。

例：計算費用表中的計劃和實際合計數(shù)。

公式：=SUMIF(B$2:G$2,B$2,B3:G3)

提示：SUMIF函數(shù)不只是左右示和，還可以上下求和。

四、SUMIF函數(shù)進階篇

SUMIF函數(shù)一般情況下只能進行一個條件的求和，但在二般情況下卻可以實現(xiàn)對多個條件的求和。什么是二般情況下呢?

SUMIF函數(shù)的第二個參數(shù)是“求和的條件”，這個參數(shù)可以用數(shù)組形式。比如

{"A","B"} {">5","<10"}

條件使用數(shù)組形式后，SUMIF會分別根據兩個條件計算出結果，然后再用SUM計算出結果。

1、對多個商品進行求和

例：如下圖所示。要求計算商品名稱為手機和冰箱的銷售之和。

公式：=SUM(SUMIF(A1:A9,{"手機","冰箱"},C2:C9))

公式說明：

SUMIF(A1:A9,{"手機","冰箱"},C2:C9) 會分別計算出手機的銷量(16)和與冰箱的銷售量(14)。返回一個數(shù)組，即：{16,14}，

SUM():對SUMIF返回的兩個銷售量進行二次求和。

2、按數(shù)字區(qū)間求和

例：如圖一所示。要求計算銷售數(shù)量大于等5，小于10的銷售數(shù)字之和。

公式：=SUM(SUMIF(C2:C9,{"<10","<5"})*{1,-1})

公式說明：

SUM(SUMIF(C2:C9,{"<10","<5"})：因為大于等5，小于10的區(qū)間和可以用<10的和減去<5的和。所以先分別計算出這兩個區(qū)間的和{21,10}

SUMIF()*{1,-1} 因為最終的結果是兩個數(shù)相減，所以這里用數(shù)組與數(shù)組的計算，把第二個數(shù)變成負數(shù){21,-10}。這樣在后面用SUM求和時就可以讓這兩個數(shù)相減了。 即SUM( {21,-10})=11